import mx.controls.Alert;	//Alert-Klasse einbinden

ctXML_xml.trigger(); 			//Externes XML-File für Databinding laden

//Beim Klick auf den Button Wetter-Alert-Box anzeigen
wetter_btn.onRelease = function()
{
	// Wurde der Service noch nicht gestartet?
	if (ctwetterservice == undefined)	{
		var mein_xml = new XML(ctXML_xml.results);	// XML einlesen

		//WSDL-URL aus der XML-Datei lesen
		var meinWSDL = mein_xml.childNodes[0].attributes.wetterwsdl;

		// WebService-Objekt mit der entsprechenden WSDL-Information anlegen
		_global.ctwetterservice = new mx.services.WebService(meinWSDL);
	}

	// Je nach Einstellung getTemperature oder getHumidity aufrufen
	if (modus_cmb.value == "Temperature") {
		var wetter = ctwetterservice.getTemperature(airport_cmb.value);
	}	else {
		var wetter = ctwetterservice.getHumidity(airport_cmb.value);
	}

	// Handler für die erfolgte Temperaturrückgabe
	wetter.onResult = function(airportWetter) {
		// Zu zeigenden Text zusammensetzen
		var endtext_txt = airportWetter + "\n\nProgramm Schliessen?";

		Alert.yesLabel 	= "Ja";						//Text für den Yes-Button ändern
		Alert.noLabel 	= "Nein";					//Text für den No-Button ändern

		// Alert-Box mit dem übersetzten Text anzeigen
		Alert.show (
			endtext_txt,										// übersetzter Text
			"Aktuelles Wetter", 						// Überschrift
			Alert.YES | Alert.NO,						// vorhandene Buttons
			_root,													// Parent für die Positionierung
			KlickHandler,										// Handlerfunktion für Buttonklicks
			"meinIcon"											// Identifier für das Icon (optional)
		);
	};
};

// Handlerfunktion für Buttonklicks
KlickHandler = function (welcherButton) {
	switch (welcherButton.detail)	{ 		// Diese Property enthält den geklickten Button
		case Alert.YES:										// Ja-Button
			fscommand("quit", "");					// Flash-Player schliessen
			break;
		case Alert.NO:										// Nein-Button
			Selection.setFocus("text_txt");	// Focus auf das Textfeld setzen
			break;
	}
}

