'© 2005, Ralf Nebelo

'***********************************************************
'OpenOffice-Brief
'***********************************************************

'Ereignis-Handler einrichten
Private WithEvents objExplorer As Explorer

'Variablen für Befehlsschaltflächen deklarieren
Public objButtonBrief As CommandBarButton
Public objButtonExport As CommandBarButton
Public objButtonOptionen As CommandBarButton

Private Sub Application_Startup()
    'Fehlerverfolgung abschalten
    On Error Resume Next

    '1. Makrostart-Schaltfläche in Befehlsleiste "Standard" anlegen
    Set objButtonBrief = OL_OOBrief.SchaltflächeAnlegen(ActiveExplorer.CommandBars("Standard"), "Neuen Brief an &Kontakt", 24, "OoBrief_Anlegen", True)
    'Wenn Schaltfläche angelegt und...
    If Not objButtonBrief Is Nothing Then
        '... aktiver Outlook-Ordner nicht "Kontakte" ist, dann...
        If ActiveExplorer.CurrentFolder.Name <> "Kontakte" Then
            '... Schaltfläche verbergen
            objButtonBrief.Visible = False
        End If
    End If

    '2. Makrostart-Schaltfläche in Befehlsleiste "Standard" anlegen
    Set objButtonExport = OL_OOBrief.SchaltflächeAnlegen(ActiveExplorer.CommandBars("Standard"), "Kontakte ex&portieren", 584, "OoBrief_Export", False)
    'Wenn Schaltfläche angelegt und...
    If Not objButtonExport Is Nothing Then
        '... aktiver Outlook-Ordner nicht "Kontakte" ist, dann...
        If ActiveExplorer.CurrentFolder.Name <> "Kontakte" Then
            '... Schaltfläche verbergen
            objButtonExport.Visible = False
        End If
    End If

    '3. Makrostart-Schaltfläche in Befehlsleiste "Standard" anlegen
    Set objButtonOptionen = OL_OOBrief.SchaltflächeAnlegen(ActiveExplorer.CommandBars("Standard"), "&Einstellungen", 548, "OoBrief_Optionen", True)
    'Wenn Schaltfläche angelegt und...
    If Not objButtonOptionen Is Nothing Then
        '... aktiver Outlook-Ordner nicht "Kontakte" ist, dann...
        If ActiveExplorer.CurrentFolder.Name <> "Kontakte" Then
            '... Schaltfläche verbergen
            objButtonOptionen.Visible = False
        End If
    End If

    'Verweis auf ActiveExplorer-Objekt einrichten und dessen Ereignisse aktivieren
    Set objExplorer = ActiveExplorer
End Sub

Private Sub objExplorer_FolderSwitch()
    'Fehlerverfolgung abschalten
    On Error Resume Next

    'Schaltflächen verbergen, wenn nicht Outlook-Ordner "Kontakte" gewählt
    objButtonBrief.Visible = ActiveExplorer.CurrentFolder.Name = "Kontakte"
    objButtonExport.Visible = objButtonBrief.Visible
    objButtonOptionen.Visible = objButtonBrief.Visible
End Sub
